maxwell/packages.nix

{ config, pkgs, lib, ... }:

let
  unstable = import <nixos-unstable> { };
in

{
  nixpkgs.overlays = lib.singleton
  (self: super:
    { maxwell-notify = self.callPackage ./custom/packages/maxwell-notify.nix
        { homeserver = "https://${config.var.hostname}/_matrix/client/r0";
          roomId     = "!FsUSHSNMPMVTFFcvJo:maxwell.ydns.eu";
          authToken  = config.secrets.passwords.matrix;
        };

      searx = super.searx.overrideAttrs (old: {
        patches = [
          # Fix a crash, remove with the next update
          (self.fetchpatch {
            url = "https://github.com/searx/searx/commit/9c10b150963babb7f0b52081693a42b2e61eede9.patch";
            sha256 = "0svp8799628wja2hq59da6rxqi99am8p6hb8y27ciwzsjz0wwba7";
          })
        ];
      });

      monero = unstable.monero;
      element-web = unstable.element-web;
    });

  environment.systemPackages = with pkgs; [
    # utilities
    iftop curl tree neovim
    nix-script openssl
    jq ack sshfs abduco

    # backup
    bup git nfs-utils

    # admin
    dnsutils
    matrix-synapse
    maxwell-notify
    smartmontools
  ];

}