{ pkgs ? import <nixpkgs> { } }:

let
  firefox = pkgs.firefox-esr-52-unwrapped.override {
    gtk3Support            = true;
    enableOfficialBranding = true;
    privacySupport         = true;
    pulseaudioSupport      = false;
  };

  patched = firefox.overrideDerivation (base: {
    patches = base.patches ++ [
      ./allow-anonymous-user-style.patch
      ./disable-datasharing-infobar.patch
      ./disable-locationservice.patch
      ./disable-sponsored-tiles.patch
      ./disable-send-to-device.patch
      ./disable-system-addons.patch
      ./disable-telemetry.patch
      ./disable-reader.patch
      ./disable-pocket.patch
      ./disable-pdfjs.patch
      ./disable-dbus.patch
      ./preferences.patch
      ./mitigate-spectre.patch
    ];

    postPatch = ''
      sed -e '/browser\/extensions/d'              \
          -e '/browser\/components\/Experiments/d' \
          -e '/browser\/features/d'                \
          -e '/pdfjs/d'                            \
          -i browser/installer/package-manifest.in
      : > browser/extensions/moz.build
    '';
    configureFlags = base.configureFlags ++ [ 
      "--disable-dbus"
      "--disable-gconf"
      "--disable-eme"
    ];
  });

in 
  pkgs.wrapFirefox patched { }