add nix expression

default.nix

@@ -0,0 +1,37 @@
+{ pkgs ? import <nixpkgs> { } }:
+
+let
+  firefox = pkgs.firefox-unwrapped.override {
+    gtk3Support            = true;
+    enableOfficialBranding = true;
+    privacySupport         = true;
+    geolocationSupport     = false;
+    pulseaudioSupport      = false;
+  };
+
+  patched = firefox.overrideDerivation (base: {
+    patches = [
+      ./disable-datasharing-infobar.patch
+      ./disable-locationservice.patch
+      ./disable-sponsored-tiles.patch
+      ./disable-telemetry.patch
+      ./disable-reader.patch
+      ./disable-pocket.patch
+      ./preferences.patch
+    ];
+    postPatch = ''
+      sed -e '/browser\/extensions/d' \
+          -e '/browser\/features/d'   \
+          -e '/pdfjs/d'               \
+          -i browser/installer/package-manifest.in
+      : > browser/extensions/moz.build
+    '';
+    configureFlags = base.configureFlags ++ [ 
+      "--disable-dbus"
+      "--disable-gconf"
+      "--disable-eme"
+    ]; 
+  });
+
+in 
+  pkgs.wrapFirefox patched { }